PETSc for Fortran Users¶
Most of the functionality of PETSc can be obtained by people who program purely in Fortran.
C vs. Fortran Interfaces¶
Only a few differences exist between the C and Fortran PETSc interfaces, are due to Fortran syntax differences. All Fortran routines have the same names as the corresponding C versions, and PETSc command line options are fully supported. The routine arguments follow the usual Fortran conventions; the user need not worry about passing pointers or values. The calling sequences for the Fortran version are in most cases identical to the C version, except for the error checking variable discussed in Error Checking and a few routines listed in Routines with Different Fortran Interfaces.
Fortran Include Files¶
The Fortran include files for PETSc are located in the directory
${PETSC_DIR}/include/petsc/finclude and should be used via
statements such as the following:
#include <petsc/finclude/petscXXX.h>
for example,
#include <petsc/finclude/petscksp.h>
You must also use the appropriate Fortran module which is done with
use petscXXX
for example,
use petscksp
Error Checking¶
In the Fortran version, each PETSc routine has as its final argument an
integer error variable, in contrast to the C convention of providing the
error variable as the routine’s return value. The error code is set to
be nonzero if an error has been detected; otherwise, it is zero. For
example, the Fortran and C variants of KSPSolve() are given,
respectively, below, where ierr denotes the error variable:
Fortran programmers can check these error codes with CHKERRQ(ierr),
which terminates all processes when an error is encountered. Likewise,
one can set error codes within Fortran programs by using
SETERRQ(comm,p,' ',ierr), which again terminates all processes upon
detection of an error. Note that complete error tracebacks with
CHKERRQ() and SETERRQ(), as described in
Simple PETSc Examples for C routines, are not directly supported for
Fortran routines; however, Fortran programmers can easily use the error
codes in writing their own tracebacks. For example, one could use code
such as the following:
call KSPSolve(ksp,b,x,ierr)
if (ierr .ne. 0) then
print*, 'Error in routine ...'
return
end if
Calling Fortran Routines from C (and C Routines from Fortran)¶
Different machines have different methods of naming Fortran routines
called from C (or C routines called from Fortran). Most Fortran
compilers change all the capital letters in Fortran routines to
lowercase. On some machines, the Fortran compiler appends an underscore
to the end of each Fortran routine name; for example, the Fortran
routine Dabsc() would be called from C with dabsc_(). Other
machines change all the letters in Fortran routine names to capitals.
PETSc provides two macros (defined in C/C++) to help write portable code
that mixes C/C++ and Fortran. They are PETSC_HAVE_FORTRAN_UNDERSCORE
and PETSC_HAVE_FORTRAN_CAPS , which are defined in the file
${PETSC_DIR}/${PETSC_ARCH}/include/petscconf.h. The macros are used,
for example, as follows:
#if defined(PETSC_HAVE_FORTRAN_CAPS)
#define dabsc_ DMDABSC
#elif !defined(PETSC_HAVE_FORTRAN_UNDERSCORE)
#define dabsc_ dabsc
#endif
.....
dabsc_( &n,x,y); /* call the Fortran function */
Passing Null Pointers¶
In several PETSc C functions, one has the option of passing a NULL (0)
argument (for example, the fifth argument of MatCreateSeqAIJ()).
From Fortran, users must pass PETSC_NULL_XXX to indicate a null
argument (where XXX is INTEGER, DOUBLE, CHARACTER, or
SCALAR depending on the type of argument required); passing 0 from
Fortran will crash the code. Note that the C convention of passing NULL
(or 0) cannot be used. For example, when no options prefix is desired
in the routine PetscOptionsGetInt(), one must use the following
command in Fortran:
call PetscOptionsGetInt(PETSC_NULL_OPTIONS,PETSC_NULL_CHARACTER,PETSC_NULL_CHARACTER,'-name',N,flg,ierr)
This Fortran requirement is inconsistent with C, where the user can
employ NULL for all null arguments.
Duplicating Multiple Vectors¶
The Fortran interface to VecDuplicateVecs() differs slightly from
the C/C++ variant because Fortran does not allow conventional arrays to
be returned in routine arguments. To create n vectors of the same
format as an existing vector, the user must declare a vector array,
v_new of size n. Then, after VecDuplicateVecs() has been
called, v_new will contain (pointers to) the new PETSc vector
objects. When finished with the vectors, the user should destroy them by
calling VecDestroyVecs(). For example, the following code fragment
duplicates v_old to form two new vectors, v_new(1) and
v_new(2).
Vec v_old, v_new(2)
PetscInt ierr
PetscScalar alpha
....
call VecDuplicateVecs(v_old,2,v_new,ierr)
alpha = 4.3
call VecSet(v_new(1),alpha,ierr)
alpha = 6.0
call VecSet(v_new(2),alpha,ierr)
....
call VecDestroyVecs(2, &v_new,ierr)
Matrix, Vector and IS Indices¶
All matrices, vectors and IS in PETSc use zero-based indexing,
regardless of whether C or Fortran is being used. The interface
routines, such as MatSetValues() and VecSetValues(), always use
zero indexing. See Basic Matrix Operations for further
details.
Setting Routines¶
When a function pointer is passed as an argument to a PETSc function,
such as the test in KSPSetConvergenceTest(), it is assumed that this
pointer references a routine written in the same language as the PETSc
interface function that was called. For instance, if
KSPSetConvergenceTest() is called from C, the test argument is
assumed to be a C function. Likewise, if it is called from Fortran, the
test is assumed to be written in Fortran.
Compiling and Linking Fortran Programs¶
Routines with Different Fortran Interfaces¶
The following Fortran routines differ slightly from their C counterparts; see the manual pages and previous discussion in this chapter for details:
PetscInitialize(char *filename,int ierr)
PetscError(MPI_COMM,int err,char *message,int ierr)
VecGetArray(), MatDenseGetArray()
ISGetIndices(),
VecDuplicateVecs(), VecDestroyVecs()
PetscOptionsGetString()
The following functions are not supported in Fortran:
PetscFClose(), PetscFOpen(), PetscFPrintf(), PetscPrintf()
PetscPopErrorHandler(), PetscPushErrorHandler()
PetscInfo()
PetscSetDebugger()
VecGetArrays(), VecRestoreArrays()
PetscViewerASCIIGetPointer(), PetscViewerBinaryGetDescriptor()
PetscViewerStringOpen(), PetscViewerStringSPrintf()
PetscOptionsGetStringArray()
PETSc includes some support for direct use of Fortran90 pointers. Current routines include:
VecGetArrayF90(), VecRestoreArrayF90()
VecGetArrayReadF90(), VecRestoreArrayReadF90()
VecDuplicateVecsF90(), VecDestroyVecsF90()
DMDAVecGetArrayF90(), DMDAVecGetArrayReadF90(), ISLocalToGlobalMappingGetIndicesF90()
MatDenseGetArrayF90(), MatDenseRestoreArrayF90()
ISGetIndicesF90(), ISRestoreIndicesF90()
See the manual pages for details and pointers to example programs.
Sample Fortran Programs¶
Sample programs that illustrate the PETSc interface for Fortran are given below, corresponding to Vec Test ex19f, Vec Tutorial ex4f, Draw Test ex5f, and SNES Tutorial ex1f, respectively. We also refer Fortran programmers to the C examples listed throughout the manual, since PETSc usage within the two languages differs only slightly.
Listing: src/vec/vec/tests/ex19f.F
!
!
program main
#include <petsc/finclude/petscvec.h>
use petscvec
implicit none
!
! This example demonstrates basic use of the PETSc Fortran interface
! to vectors.
!
PetscInt n
PetscErrorCode ierr
PetscBool flg
PetscScalar one,two,three,dot
PetscReal norm,rdot
Vec x,y,w
PetscOptions options
n = 20
one = 1.0
two = 2.0
three = 3.0
call PetscInitialize(PETSC_NULL_CHARACTER,ierr)
if (ierr .ne. 0) then
print*,'Unable to initialize PETSc'
stop
endif
call PetscOptionsCreate(options,ierr)
call PetscOptionsGetInt(options,PETSC_NULL_CHARACTER, &
& '-n',n,flg,ierr)
call PetscOptionsDestroy(options,ierr)
! Create a vector, then duplicate it
call VecCreate(PETSC_COMM_WORLD,x,ierr)
call VecSetSizes(x,PETSC_DECIDE,n,ierr)
call VecSetFromOptions(x,ierr)
call VecDuplicate(x,y,ierr)
call VecDuplicate(x,w,ierr)
call VecSet(x,one,ierr)
call VecSet(y,two,ierr)
call VecDot(x,y,dot,ierr)
rdot = PetscRealPart(dot)
write(6,100) rdot
100 format('Result of inner product ',f10.4)
call VecScale(x,two,ierr)
call VecNorm(x,NORM_2,norm,ierr)
write(6,110) norm
110 format('Result of scaling ',f10.4)
call VecCopy(x,w,ierr)
call VecNorm(w,NORM_2,norm,ierr)
write(6,120) norm
120 format('Result of copy ',f10.4)
call VecAXPY(y,three,x,ierr)
call VecNorm(y,NORM_2,norm,ierr)
write(6,130) norm
130 format('Result of axpy ',f10.4)
call VecDestroy(x,ierr)
call VecDestroy(y,ierr)
call VecDestroy(w,ierr)
call PetscFinalize(ierr)
end
!/*TEST
!
! test:
!
!TEST*/
Listing: src/vec/vec/tutorials/ex4f.F
!
!
! Description: Illustrates the use of VecSetValues() to set
! multiple values at once; demonstrates VecGetArray().
!
!/*T
! Concepts: vectors^assembling;
! Concepts: vectors^arrays of vectors;
! Processors: 1
!T*/
! -----------------------------------------------------------------------
program main
#include <petsc/finclude/petscvec.h>
use petscvec
implicit none
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Macro definitions
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
! Macros to make clearer the process of setting values in vectors and
! getting values from vectors.
!
! - The element xx_a(ib) is element ib+1 in the vector x
! - Here we add 1 to the base array index to facilitate the use of
! conventional Fortran 1-based array indexing.
!
#define xx_a(ib) xx_v(xx_i + (ib))
#define yy_a(ib) yy_v(yy_i + (ib))
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Beginning of program
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
PetscScalar xwork(6)
PetscScalar xx_v(1),yy_v(1)
PetscInt i,n,loc(6),isix
PetscErrorCode ierr
PetscOffset xx_i,yy_i
Vec x,y
call PetscInitialize(PETSC_NULL_CHARACTER,ierr)
if (ierr .ne. 0) then
print*,'PetscInitialize failed'
stop
endif
n = 6
isix = 6
! Create initial vector and duplicate it
call VecCreateSeq(PETSC_COMM_SELF,n,x,ierr)
call VecDuplicate(x,y,ierr)
! Fill work arrays with vector entries and locations. Note that
! the vector indices are 0-based in PETSc (for both Fortran and
! C vectors)
do 10 i=1,n
loc(i) = i-1
xwork(i) = 10.0*real(i)
10 continue
! Set vector values. Note that we set multiple entries at once.
! Of course, usually one would create a work array that is the
! natural size for a particular problem (not one that is as long
! as the full vector).
call VecSetValues(x,isix,loc,xwork,INSERT_VALUES,ierr)
! Assemble vector
call VecAssemblyBegin(x,ierr)
call VecAssemblyEnd(x,ierr)
! View vector
call PetscObjectSetName(x, 'initial vector:',ierr)
call VecView(x,PETSC_VIEWER_STDOUT_SELF,ierr)
call VecCopy(x,y,ierr)
! Get a pointer to vector data.
! - For default PETSc vectors, VecGetArray() returns a pointer to
! the data array. Otherwise, the routine is implementation dependent.
! - You MUST call VecRestoreArray() when you no longer need access to
! the array.
! - Note that the Fortran interface to VecGetArray() differs from the
! C version. See the users manual for details.
call VecGetArray(x,xx_v,xx_i,ierr)
call VecGetArray(y,yy_v,yy_i,ierr)
! Modify vector data
do 30 i=1,n
xx_a(i) = 100.0*real(i)
yy_a(i) = 1000.0*real(i)
30 continue
! Restore vectors
call VecRestoreArray(x,xx_v,xx_i,ierr)
call VecRestoreArray(y,yy_v,yy_i,ierr)
! View vectors
call PetscObjectSetName(x, 'new vector 1:',ierr)
call VecView(x,PETSC_VIEWER_STDOUT_SELF,ierr)
call PetscObjectSetName(y, 'new vector 2:',ierr)
call VecView(y,PETSC_VIEWER_STDOUT_SELF,ierr)
! Free work space. All PETSc objects should be destroyed when they
! are no longer needed.
call VecDestroy(x,ierr)
call VecDestroy(y,ierr)
call PetscFinalize(ierr)
end
!/*TEST
!
! test:
!
!TEST*/
Listing: src/sys/classes/draw/tests/ex5f.F
!
!
program main
#include <petsc/finclude/petscsys.h>
#include <petsc/finclude/petscdraw.h>
use petscsys
implicit none
!
! This example demonstrates basic use of the Fortran interface for
! PetscDraw routines.
!
PetscDraw draw
PetscDrawLG lg
PetscDrawAxis axis
PetscErrorCode ierr
PetscBool flg
integer x,y,width,height
PetscScalar xd,yd
PetscReal ten
PetscInt i,n,w,h
PetscInt one
n = 15
x = 0
y = 0
w = 400
h = 300
ten = 10.0
one = 1
call PetscInitialize(PETSC_NULL_CHARACTER,ierr)
if (ierr .ne. 0) then
print*,'Unable to initialize PETSc'
stop
endif
! GetInt requires a PetscInt so have to do this ugly setting
call PetscOptionsGetInt(PETSC_NULL_OPTIONS,PETSC_NULL_CHARACTER, &
& '-width',w, flg,ierr)
width = int(w)
call PetscOptionsGetInt(PETSC_NULL_OPTIONS,PETSC_NULL_CHARACTER, &
& '-height',h,flg,ierr)
height = int(h)
call PetscOptionsGetInt(PETSC_NULL_OPTIONS,PETSC_NULL_CHARACTER, &
& '-n',n,flg,ierr)
call PetscDrawCreate(PETSC_COMM_WORLD,PETSC_NULL_CHARACTER, &
& PETSC_NULL_CHARACTER,x,y,width,height,draw,ierr)
call PetscDrawSetFromOptions(draw,ierr)
call PetscDrawLGCreate(draw,one,lg,ierr)
call PetscDrawLGGetAxis(lg,axis,ierr)
call PetscDrawAxisSetColors(axis,PETSC_DRAW_BLACK,PETSC_DRAW_RED, &
& PETSC_DRAW_BLUE,ierr)
call PetscDrawAxisSetLabels(axis,'toplabel','xlabel','ylabel', &
& ierr)
do 10, i=0,n-1
xd = real(i) - 5.0
yd = xd*xd
call PetscDrawLGAddPoint(lg,xd,yd,ierr)
10 continue
call PetscDrawLGSetUseMarkers(lg,PETSC_TRUE,ierr)
call PetscDrawLGDraw(lg,ierr)
call PetscSleep(ten,ierr)
call PetscDrawLGDestroy(lg,ierr)
call PetscDrawDestroy(draw,ierr)
call PetscFinalize(ierr)
end
!/*TEST
!
! build:
! requires: x
!
! test:
! output_file: output/ex1_1.out
!
!TEST*/
Listing: src/snes/tutorials/ex1f.F90
!
!
! Description: Uses the Newton method to solve a two-variable system.
!
!!/*T
! Concepts: SNES^basic uniprocessor example
! Processors: 1
!T*/
program main
#include <petsc/finclude/petsc.h>
use petsc
implicit none
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Variable declarations
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
! Variables:
! snes - nonlinear solver
! ksp - linear solver
! pc - preconditioner context
! ksp - Krylov subspace method context
! x, r - solution, residual vectors
! J - Jacobian matrix
! its - iterations for convergence
!
SNES snes
PC pc
KSP ksp
Vec x,r
Mat J
SNESLineSearch linesearch
PetscErrorCode ierr
PetscInt its,i2,i20
PetscMPIInt size,rank
PetscScalar pfive
PetscReal tol
PetscBool setls
#if defined(PETSC_USE_LOG)
PetscViewer viewer
#endif
double precision threshold,oldthreshold
! Note: Any user-defined Fortran routines (such as FormJacobian)
! MUST be declared as external.
external FormFunction, FormJacobian, MyLineSearch
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Macro definitions
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
! Macros to make clearer the process of setting values in vectors and
! getting values from vectors. These vectors are used in the routines
! FormFunction() and FormJacobian().
! - The element lx_a(ib) is element ib in the vector x
!
#define lx_a(ib) lx_v(lx_i + (ib))
#define lf_a(ib) lf_v(lf_i + (ib))
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Beginning of program
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
call PetscInitialize(PETSC_NULL_CHARACTER,ierr)
if (ierr .ne. 0) then
print*,'Unable to initialize PETSc'
stop
endif
call PetscLogNestedBegin(ierr);CHKERRA(ierr)
threshold = 1.0
call PetscLogSetThreshold(threshold,oldthreshold,ierr)
! dummy test of logging a reduction
#if defined(PETSC_USE_LOG)
ierr = PetscAReduce()
#endif
call MPI_Comm_size(PETSC_COMM_WORLD,size,ierr)
call MPI_Comm_rank(PETSC_COMM_WORLD,rank,ierr)
if (size .ne. 1) then; SETERRA(PETSC_COMM_SELF,PETSC_ERR_WRONG_MPI_SIZE,'Uniprocessor example'); endif
i2 = 2
i20 = 20
! - - - - - - - - - -- - - - - - - - - - - - - - - - - - - - - - - - - -
! Create nonlinear solver context
! - - - - - - - - - -- - - - - - - - - - - - - - - - - - - - - - - - - -
call SNESCreate(PETSC_COMM_WORLD,snes,ierr)
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Create matrix and vector data structures; set corresponding routines
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Create vectors for solution and nonlinear function
call VecCreateSeq(PETSC_COMM_SELF,i2,x,ierr)
call VecDuplicate(x,r,ierr)
! Create Jacobian matrix data structure
call MatCreate(PETSC_COMM_SELF,J,ierr)
call MatSetSizes(J,PETSC_DECIDE,PETSC_DECIDE,i2,i2,ierr)
call MatSetFromOptions(J,ierr)
call MatSetUp(J,ierr)
! Set function evaluation routine and vector
call SNESSetFunction(snes,r,FormFunction,0,ierr)
! Set Jacobian matrix data structure and Jacobian evaluation routine
call SNESSetJacobian(snes,J,J,FormJacobian,0,ierr)
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Customize nonlinear solver; set runtime options
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Set linear solver defaults for this problem. By extracting the
! KSP, KSP, and PC contexts from the SNES context, we can then
! directly call any KSP, KSP, and PC routines to set various options.
call SNESGetKSP(snes,ksp,ierr)
call KSPGetPC(ksp,pc,ierr)
call PCSetType(pc,PCNONE,ierr)
tol = 1.e-4
call KSPSetTolerances(ksp,tol,PETSC_DEFAULT_REAL, &
& PETSC_DEFAULT_REAL,i20,ierr)
! Set SNES/KSP/KSP/PC runtime options, e.g.,
! -snes_view -snes_monitor -ksp_type <ksp> -pc_type <pc>
! These options will override those specified above as long as
! SNESSetFromOptions() is called _after_ any other customization
! routines.
call SNESSetFromOptions(snes,ierr)
call PetscOptionsHasName(PETSC_NULL_OPTIONS,PETSC_NULL_CHARACTER, &
& '-setls',setls,ierr)
if (setls) then
call SNESGetLineSearch(snes, linesearch, ierr)
call SNESLineSearchSetType(linesearch, 'shell', ierr)
call SNESLineSearchShellSetUserFunc(linesearch, MyLineSearch, &
& 0, ierr)
endif
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Evaluate initial guess; then solve nonlinear system
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Note: The user should initialize the vector, x, with the initial guess
! for the nonlinear solver prior to calling SNESSolve(). In particular,
! to employ an initial guess of zero, the user should explicitly set
! this vector to zero by calling VecSet().
pfive = 0.5
call VecSet(x,pfive,ierr)
call SNESSolve(snes,PETSC_NULL_VEC,x,ierr)
! View solver converged reason; we could instead use the option -snes_converged_reason
call SNESConvergedReasonView(snes,PETSC_VIEWER_STDOUT_WORLD,ierr)
call SNESGetIterationNumber(snes,its,ierr);
if (rank .eq. 0) then
write(6,100) its
endif
100 format('Number of SNES iterations = ',i5)
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Free work space. All PETSc objects should be destroyed when they
! are no longer needed.
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
call VecDestroy(x,ierr)
call VecDestroy(r,ierr)
call MatDestroy(J,ierr)
call SNESDestroy(snes,ierr)
#if defined(PETSC_USE_LOG)
call PetscViewerASCIIOpen(PETSC_COMM_WORLD,'filename.xml',viewer,ierr)
call PetscViewerPushFormat(viewer,PETSC_VIEWER_ASCII_XML,ierr)
call PetscLogView(viewer,ierr)
call PetscViewerDestroy(viewer,ierr)
#endif
call PetscFinalize(ierr)
end
!
! ------------------------------------------------------------------------
!
! FormFunction - Evaluates nonlinear function, F(x).
!
! Input Parameters:
! snes - the SNES context
! x - input vector
! dummy - optional user-defined context (not used here)
!
! Output Parameter:
! f - function vector
!
subroutine FormFunction(snes,x,f,dummy,ierr)
use petscsnes
implicit none
SNES snes
Vec x,f
PetscErrorCode ierr
integer dummy(*)
! Declarations for use with local arrays
PetscScalar lx_v(2),lf_v(2)
PetscOffset lx_i,lf_i
! Get pointers to vector data.
! - For default PETSc vectors, VecGetArray() returns a pointer to
! the data array. Otherwise, the routine is implementation dependent.
! - You MUST call VecRestoreArray() when you no longer need access to
! the array.
! - Note that the Fortran interface to VecGetArray() differs from the
! C version. See the Fortran chapter of the users manual for details.
call VecGetArrayRead(x,lx_v,lx_i,ierr)
call VecGetArray(f,lf_v,lf_i,ierr)
! Compute function
lf_a(1) = lx_a(1)*lx_a(1) &
& + lx_a(1)*lx_a(2) - 3.0
lf_a(2) = lx_a(1)*lx_a(2) &
& + lx_a(2)*lx_a(2) - 6.0
! Restore vectors
call VecRestoreArrayRead(x,lx_v,lx_i,ierr)
call VecRestoreArray(f,lf_v,lf_i,ierr)
return
end
! ---------------------------------------------------------------------
!
! FormJacobian - Evaluates Jacobian matrix.
!
! Input Parameters:
! snes - the SNES context
! x - input vector
! dummy - optional user-defined context (not used here)
!
! Output Parameters:
! A - Jacobian matrix
! B - optionally different preconditioning matrix
! flag - flag indicating matrix structure
!
subroutine FormJacobian(snes,X,jac,B,dummy,ierr)
use petscsnes
implicit none
SNES snes
Vec X
Mat jac,B
PetscScalar A(4)
PetscErrorCode ierr
PetscInt idx(2),i2
integer dummy(*)
! Declarations for use with local arrays
PetscScalar lx_v(2)
PetscOffset lx_i
! Get pointer to vector data
i2 = 2
call VecGetArrayRead(x,lx_v,lx_i,ierr)
! Compute Jacobian entries and insert into matrix.
! - Since this is such a small problem, we set all entries for
! the matrix at once.
! - Note that MatSetValues() uses 0-based row and column numbers
! in Fortran as well as in C (as set here in the array idx).
idx(1) = 0
idx(2) = 1
A(1) = 2.0*lx_a(1) + lx_a(2)
A(2) = lx_a(1)
A(3) = lx_a(2)
A(4) = lx_a(1) + 2.0*lx_a(2)
call MatSetValues(B,i2,idx,i2,idx,A,INSERT_VALUES,ierr)
! Restore vector
call VecRestoreArrayRead(x,lx_v,lx_i,ierr)
! Assemble matrix
call MatAssemblyBegin(B,MAT_FINAL_ASSEMBLY,ierr)
call MatAssemblyEnd(B,MAT_FINAL_ASSEMBLY,ierr)
if (B .ne. jac) then
call MatAssemblyBegin(jac,MAT_FINAL_ASSEMBLY,ierr)
call MatAssemblyEnd(jac,MAT_FINAL_ASSEMBLY,ierr)
endif
return
end
subroutine MyLineSearch(linesearch, lctx, ierr)
use petscsnes
implicit none
SNESLineSearch linesearch
SNES snes
integer lctx
Vec x, f,g, y, w
PetscReal ynorm,gnorm,xnorm
PetscBool flag
PetscErrorCode ierr
PetscScalar mone
mone = -1.0
call SNESLineSearchGetSNES(linesearch, snes, ierr)
call SNESLineSearchGetVecs(linesearch, x, f, y, w, g, ierr)
call VecNorm(y,NORM_2,ynorm,ierr)
call VecAXPY(x,mone,y,ierr)
call SNESComputeFunction(snes,x,f,ierr)
call VecNorm(f,NORM_2,gnorm,ierr)
call VecNorm(x,NORM_2,xnorm,ierr)
call VecNorm(y,NORM_2,ynorm,ierr)
call SNESLineSearchSetNorms(linesearch, xnorm, gnorm, ynorm, &
& ierr)
flag = PETSC_FALSE
return
end
!/*TEST
!
! test:
! args: -ksp_gmres_cgs_refinement_type refine_always -snes_monitor_short
! requires: !single
!
!TEST*/
Array Arguments¶
This material is no longer relevent since one should use
VecGetArrayF90() and the other routines that utilize Fortran
pointers, instead of the code below, but it is included for historical
reasons and because many of the Fortran examples still utilize the old
approach.
Since Fortran 77 does not allow arrays to be returned in routine
arguments, all PETSc routines that return arrays, such as
VecGetArray(), MatDenseGetArray(), and ISGetIndices(), are
defined slightly differently in Fortran than in C. Instead of returning
the array itself, these routines accept as input a user-specified array
of dimension one and return an integer index to the actual array used
for data storage within PETSc. The Fortran interface for several
routines is as follows:
PetscScalar xx_v(1), aa_v(1)
PetscErrorCode ierr
PetscInt ss_v(1), dd_v(1), nloc
PetscOffset ss_i, xx_i, aa_i, dd_i
Vec x
Mat A
IS s
DM d
call VecGetArray(x,xx_v,xx_i,ierr)
call MatDenseGetArray(A,aa_v,aa_i,ierr)
call ISGetIndices(s,ss_v,ss_i,ierr)
To access array elements directly, both the user-specified array and the
integer index must then be used together. For example, the following
Fortran program fragment illustrates directly setting the values of a
vector array instead of using VecSetValues(). Note the (optional)
use of the preprocessor #define statement to enable array
manipulations in the conventional Fortran manner.
#define xx_a(ib) xx_v(xx_i + (ib))
double precision xx_v(1)
PetscOffset xx_i
PetscErrorCode ierr
PetscInt i, n
Vec x
call VecGetArray(x,xx_v,xx_i,ierr)
call VecGetLocalSize(x,n,ierr)
do 10, i=1,n
xx_a(i) = 3*i + 1
10 continue
call VecRestoreArray(x,xx_v,xx_i,ierr)
The Vec ex4f Tutorial listed above contains an example of
using VecGetArray() within a Fortran routine.
Since in this case the array is accessed directly from Fortran, indexing
begins with 1, not 0 (unless the array is declared as xx_v(0:1)).
This is different from the use of VecSetValues() where, indexing
always starts with 0.
Note: If using VecGetArray(), MatDenseGetArray(), or
ISGetIndices(), from Fortran, the user must not compile the
Fortran code with options to check for “array entries out of bounds”
(e.g., on the IBM RS/6000 this is done with the -C compiler option,
so never use the -C option with this).